.TITLE	DRCMT
	.IDENT	/5.1/
 
;
; Copyright (c) 1995-1999 by Mentec, Inc., U.S.A.
; All rights reserved
;
;
; THIS SOFTWARE IS FURNISHED UNDER A LICENSE AND MAY BE USED
; OR COPIED ONLY IN ACCORDANCE WITH THE TERMS OF SUCH LICENSE.
;
; MODIFIED FOR VERSION 2.1 BY:
;
;	J. R. KAUFFMAN		17-OCT-82	5.1
;
;		JRK263 -- MOVE MORE CODE TO DIRECTIVE COMMON
;
;
; CANCEL MARK TIME AND SCHEDULE REQUESTS DIRECTIVES
;
; MACRO LIBRARY CALLS
;

	.MCALL	CLKDF$
	CLKDF$			;DEFINE CLOCK QUEUE CONTROL BLOCK OFFSETS

;+
; **-$DRCMT-CANCEL MARK TIME REQUESTS
; **-$DRCMS-CANCEL SELECTIVE MARK TIME REQUESTS				
;
; THIS DIRECTIVE INSTRUCTS THE SYSTEM TO CANCEL ALL MARK TIME REQUESTS
; (DPB SIZE=1) OR ALL REQUESTS WITH MATCHING EVENT FLAG OR AST ADDRESS	
; (DPB SIZE=3).								
;									
; DPB FORMAT.
;
;	WD. 00 -- DIC(27.),DPB SIZE(1. OR 3.).				
;	WD. 01 -- MATCHING EFN NUMBER					
;	WD. 02 -- MATCHING AST ADDRESS					
;									
; INPUTS:
;
;	R2=ADDRESS OF THE TASK STATUS WORD OF THE CURRENT TASK.
;	R3=ADDRESS OF WD. 00 + 2.					
;	R4=ADDRESS OF THE HEADER OF THE CURRENT TASK.			
;	R5=ADDRESS OF THE TCB OF THE CURRENT TASK.
;
;	NOTE: $DRCMT IS ALSO CALLED FROM THE EXIT DIRECTIVE AND		
;		ONLY REQUIRES R5 TO BE LOADED ON ENTRANCE.		
;
; OUTPUTS: (DIRECTIVE STATUS AND PS RETURNED TO TASK)
;
;	C=0 WITH A DIRECTIVE STATUS OF +1.
;-

	.ENABL	LSB
$DRCMS::CMPB	-(R3),#1	;DPB SIZE=1				
	BEQ	$DRCMT		;IF EQ YES, CANCEL ALL MARK TIMES	
	CMPB	(R3)+,#3	;DPB SIZE=3				
	BNE	5$		;IF NE NO, INVALID DPB SIZE		
	MOV	(R3)+,R1	;PICK UP SPECIFIED EFN			
	MOV	(R3),R2		;PICK UP SPECIFIED AST ADDRESS		
	CLR	R4		;SET MARK TIME CODE			
	CALLR	$CLRSM		;CANCEL SELECTED MARK TIMES		
$DRCMT::CLR	R4		;SET TYPE OF REQUEST TO REMOVE
	CALLR	$CLRMV		;REMOVE ALL REMAINING ENTRIES
5$:	DRSTS	D.RS99		;INVALID DPB SIZE			

	.END